4.32 Formatted Write

The current version of SWI-Prolog provides two formatted write predicates. The‘writef' family (writef/1, writef/2, swritef/3), is compatible with Edinburgh C-Prolog and should be considered deprecated. The‘format' family (format/1, format/2, format/3), was defined by Quintus Prolog and currently available in many Prolog systems, although the details vary.

4.32.1 Writef

[deprecated]writef(+Atom)

Equivalent to writef(Atom, []). See writef/2 for details.

[deprecated]writef(+Format, +Arguments)

Formatted write. Format is an atom whose characters will be printed. Format may contain certain special character sequences which specify certain formatting and substitution actions. Arguments provides all the terms required to be output.

Escape sequences to generate a single special character:

\n	Output a newline character (see also nl/[0,1])
\l	Output a line separator (same as \n)
\r	Output a carriage return character (ASCII 13)
\t	Output the ASCII character TAB (9)
\\	The character \ is output
\%	The character % is output
\nnn	where <nnn> is an integer (1-3 digits); the character with code <nnn> is output (NB : <nnn> is read as decimal)

Note that \l, \nnn and \\ are interpreted differently when character escapes are in effect. See section 2.16.1.3.

Escape sequences to include arguments from Arguments. Each time a % escape sequence is found in Format the next argument from Arguments is formatted according to the specification.

%t	print/1 the next item (mnemonic: term)
%w	write/1 the next item
%q	writeq/1 the next item
%d	Write the term, ignoring operators. See also write_term/2. Mnemonic: old Edinburgh display/1
%p	print/1 the next item (identical to %t)
%n	Put the next item as a character (i.e., it is a character code)
%r	Write the next item N times where N is the second item (an integer)
%s	Write the next item as a String (so it must be a list of characters)
%f	Perform a ttyflush/0 (no items used)
%Nc	Write the next item Centered in N columns
%Nl	Write the next item Left justified in N columns
%Nr	Write the next item Right justified in N columns. N is a decimal number with at least one digit. The item must be an atom, integer, float or string.

[deprecated]swritef(-String, +Format, +Arguments)

Equivalent to writef/2, but “writes'' the result on String instead of the current output stream. Example:

?- swritef(S, '%15L%w', ['Hello', 'World']).

S = "Hello          World"

[deprecated]swritef(-String, +Format)

Equivalent to swritef(String, Format, []).

4.32.2 Format

The format family of predicates is the most versatile and portable^{143Unfortunately not covered by any standard.} way to produce textual output.

format(+Format)

Defined as‘format(Format) :- format(Format, []).’. See format/2 for details.

format(+Format, :Arguments)

Format is an atom, list of character codes, or a Prolog string. Arguments provides the arguments required by the format specification. If only one argument is required and this single argument is not a list, the argument need not be put in a list. Otherwise the arguments are put in a list.

Special sequences start with the tilde (~), followed by an optional numeric argument, optionally followed by a colon modifier (:), ^{144The colon modifiers is a SWI-Prolog extension, proposed by Richard O'Keefe.} followed by a character describing the action to be undertaken. A numeric argument is either a sequence of digits, representing a positive decimal number, a sequence ‘<character>, representing the character code value of the character (only useful for ~t) or a asterisk (*), in which case the numeric argument is taken from the next argument of the argument list, which should be a positive integer. E.g., the following three examples all pass 46 (.) to ~t:

?- format('~w ~46t ~w~72|~n', ['Title', 'Page']).
?- format('~w ~`.t ~w~72|~n', ['Title', 'Page']).
?- format('~w ~*t ~w~72|~n', ['Title', 46, 'Page']).

Some format expressions may call back Prolog, i.e., ~p, ~W, ~@ and user defined extensions registered with format_predicate/2. Output written to the stream current_output is merged into the format/2 output. If there is no pending rubber (~t) and the the position notation aligns, only the output is switched. Otherwise the output is captured in a temporary memory buffer and emitted after the callback finishes. The system attempts to preserve the position and alignment promises. It sets the tty property of the temporary stream to reflect the main stream and uses the position information of the temporary stream to update its notion of the position. Notable ansi_format/3 cooperates properly in callbacks.^{145As of version 8.3.30}.

Numeric conversion (d, D, e, E, f, g and G) accept an arithmetic expression as argument. This is introduced to handle rational numbers transparently (see section 4.27.2.2). The floating point conversions allow for unlimited precision for printing rational numbers in decimal form. E.g., the following will write as many 3's as you want by changing the‘50'.

?- format('~50f', [10 rdiv 3]).
3.33333333333333333333333333333333333333333333333333

• ~
  Output the tilde itself.

• a
  Output the next argument, which must be an atom. This option is equivalent to w, except that it requires the argument to be an atom.

• c
  Interpret the next argument as a character code and add it to the output. This argument must be a valid Unicode character code. Note that the actually emitted bytes are defined by the character encoding of the output stream and an exception may be raised if the output stream is not capable of representing the requested Unicode character. See section 2.19.1 for details.

• d
  Output next argument as a decimal number. It should be an integer. If a numeric argument is specified, a dot is inserted argument positions from the right (useful for doing fixed point arithmetic with integers, such as handling amounts of money).

  The colon modifier (e.g., ~:d) causes the number to be printed according to the locale of the output stream. See section 4.23.

• D
  Same as d, but makes large values easier to read by inserting a comma every three digits left or right of the dot. This is the same as ~:d, but using the fixed English locale.

• e
  Output next argument as a floating point number in exponential notation. The numeric argument specifies the precision. Default is 6 digits. Exact representation depends on the C library function printf(). This function is invoked with the format %.<precision>e.

• E
  Equivalent to e, but outputs a capital E to indicate the exponent.

• f
  Floating point in non-exponential notation. The numeric argument defines the number of digits right of the decimal point. If the numeric argument is zero (0), the value is printed as an integer. If the colon modifier (:) is used, the float is formatted using conventions from the current locale, which may define the decimal point as well as grouping of digits left of the decimal point.

• g
  Floating point in e or f notation, whichever is shorter.

• G
  Floating point in E or f notation, whichever is shorter.

• i
  Ignore next argument of the argument list. Produces no output.

• I
  Emit a decimal number using Prolog digit grouping (the underscore, _). The argument describes the size of each digit group. The default is 3. See also section 2.16.1.5. For example:

  ?- A is 1<<100, format('~10I', [A]).
  1_2676506002_2822940149_6703205376
  

• k
  Give the next argument to write_canonical/1.
• n
  Output a newline character.
• N
  Only output a newline if the last character output on this stream was not a newline. Not properly implemented yet.
• p
  Give the next argument to print/1.
• q
  Give the next argument to writeq/1.

• r
  Print integer in radix numeric argument notation (default 8). Thus ~16r prints its argument hexadecimal. The argument should be in the range [2, ... , 36]. Lowercase letters are used for digits above 9. The colon modifier may be used to form locale-specific digit groups.

• R
  Same as r, but uses uppercase letters for digits above 9.
• s
  Output text from a list of character codes, characters, string (see string/1 and section 5.2) or atom from the next argument. If an numeric argument is given the string is truncated to this number of characters.

• @
  Interpret the next argument as a goal and execute it. Output written to the current_output stream is inserted at this place. Goal is called in the module calling format/3. This option is not present in the original definition by Quintus, but supported by some other Prolog systems. The goal is executed as \+ \+ Goal, i.e., bindings created by the goal are discarded.

• t
  All remaining space between 2 tab stops is distributed equally over ~t statements between the tab stops. This space is padded with spaces by default. If an argument is supplied, it is taken to be the character code of the character used for padding. This can be used to do left or right alignment, centering, distributing, etc. See also ~| and ~+ to set tab stops. A tab stop is assumed at the start of each line.
• |
  Set a tab stop on the current position. If an argument is supplied set a tab stop on the position of that argument. This will cause all ~t’s to be distributed between the previous and this tab stop.

  If the current column is at or past the requested tabstop and the modifier (:) is used, a newline is inserted and the padding character of the last ~t is used to pad to the requested position.

• +
  Set a tab stop (as ~|) relative to the last tab stop or the beginning of the line if no tab stops are set before the ~+. This constructs can be used to fill fields. The partial format sequence below prints an integer right-aligned and padded with zeros in 6 columns. The ... sequences in the example illustrate that the integer is aligned in 6 columns regardless of the remainder of the format specification.

          format('...~|~`0t~d~6+...', [..., Integer, ...])
  

• w
  Give the next argument to write/1.
• W
  Give the next two arguments to write_term/2. For example, format('~W', [Term, [numbervars(true)]]). This option is SWI-Prolog specific.

Example:

simple_statistics :-
    <obtain statistics>         % left to the user
    format('~tStatistics~t~72|~n~n'),
    format('Runtime: ~`.t ~2f~34|  Inferences: ~`.t ~D~72|~n',
                                            [RunT, Inf]),
    ....

will output

                             Statistics

Runtime: .................. 3.45  Inferences: .......... 60,345

format(+Output, +Format, :Arguments)

As format/2, but write the output on the given Output. The de-facto standard only allows Output to be a stream. The SWI-Prolog implementation allows all valid arguments for with_output_to/2.^{146Earlier versions defined sformat/3 . These predicates have been moved to the library library(backcomp).} For example:

?- format(atom(A), '~D', [1000000]).
A = '1,000,000'

4.32.3 Programming Format

format_predicate(+Char, +Head)

If a sequence ~c (tilde, followed by some character) is found, the format/3 and friends first check whether the user has defined a predicate to handle the format. If not, the built-in formatting rules described above are used. Char is either a character code or a one-character atom, specifying the letter to be (re)defined. Head is a term, whose name and arity are used to determine the predicate to call for the redefined formatting character. The first argument to the predicate is the numeric argument of the format command, or the atom default if no argument is specified. The remaining arguments are filled from the argument list. The example below defines ~T to print a timestamp in ISO8601 format (see format_time/3). The subsequent block illustrates a possible call.

:- format_predicate('T', format_time(_Arg,_Time)).

format_time(_Arg, Stamp) :-
        must_be(number, Stamp),
        format_time(current_output, '%FT%T%z', Stamp).

?- get_time(Now),
   format('Now, it is ~T~n', [Now]).
Now, it is 2012-06-04T19:02:01+0200
Now = 1338829321.6620328.

current_format_predicate(?Code, ?:Head)

True when ~Code is handled by the user-defined predicate specified by Head.